Naar de inhoud

Excel-functie · in Engelse Excel RIGHT

RECHTSin Excel

RECHTS geeft de laatste tekens van een tekst terug, geteld vanaf rechts. Daarmee pak je bijvoorbeeld het volgnummer achter een ordernummer, de laatste cijfers van een rekeningnummer of de extensie van een bestandsnaam. In Engelse Excel heet de functie RIGHT.

=RECHTS(tekst; [aantal_tekens])Engelse Excel: =RIGHT(text, [num_chars])

De syntaxis van RECHTS

Nederlandse Excel: =RECHTS(tekst; [aantal_tekens]). Engelse Excel: =RIGHT(text, [num_chars]).

  • tekst: de tekst of cel waaruit je wilt knippen.
  • aantal_tekens: hoeveel tekens je van rechts wilt hebben. Zonder dit argument krijg je één teken. Vraag je meer tekens dan er zijn, dan krijg je gewoon de hele tekst.

Tussen de argumenten zet je met Nederlandse landinstellingen een puntkomma, ook als je Excel in het Engels gebruikt.

Voorbeeld: het volgnummer van een order

Ordernummers zien eruit als NL-2026-0042: land, jaar en een volgnummer van vier cijfers. Het volgnummer krijg je met =RECHTS(A2;4).

Net als bij LINKS is de uitkomst tekst: 0042, met de voorloopnullen erbij. Wil je er een getal van maken, gebruik dan =WAARDE(RECHTS(A2;4)). Dan wordt het 42.

Alles na een spatie of streepje

Is het laatste stuk niet altijd even lang, reken dan uit hoeveel tekens je nodig hebt. LENGTE geeft de totale lengte, VIND.SPEC de positie van het scheidingsteken. Alles na de eerste spatie krijg je zo: =RECHTS(A2;LENGTE(A2)-VIND.SPEC(" ";A2)).

Voor een naam als Jansen, Pieter haal je met =RECHTS(A2;LENGTE(A2)-VIND.SPEC(", ";A2)-1) de voornaam eruit. In Microsoft 365 is =TEKST.NA(A2;", ") korter en leesbaarder.

RECHTS, LINKS en DEEL

  • LINKS pakt tekens aan het begin.
  • RECHTS pakt tekens aan het eind.
  • DEEL pakt tekens vanaf een positie die je zelf kiest.

Alle drie werken op de tekst zoals die in de cel staat, niet op hoe Excel hem toont. Bij datums en opgemaakte bedragen geeft dat verrassingen, zie de fouten hieronder.

Praktijkvoorbeelden met RECHTS

  • Postcodeletters: =RECHTS(B2;2) haalt AB uit 1012 AB.
  • Jaartal achteraan een code: =RECHTS(A2;4) bij codes als PROJ-2026.
  • Valuta: =RECHTS(A2;3) haalt EUR uit een tekst als 125,00 EUR.
  • Alleen de laatste vier cijfers van een rekeningnummer tonen: ="xxxx "&RECHTS(A2;4).

Moet een nummer altijd even lang zijn, dan kun je RECHTS ook andersom gebruiken: =RECHTS("0000"&A2;4) maakt van 42 de tekst 0042.

Veelgemaakte fouten met RECHTS

RECHTS op een datum

Een datum is voor Excel een getal, zoals 46097 voor 16 maart 2026. =RECHTS(B2;4) geeft dan 6097 en niet het jaartal. Gebruik voor datums JAAR, of zet de datum eerst om met TEKST.

Spaties aan het eind

Staat er een spatie achter de tekst, dan is dat het laatste teken en schuift alles één plek op. Ruim de cel eerst op: =RECHTS(SPATIES.WISSEN(A2);4).

Vergelijken met een getal

De uitkomst 0042 is tekst. Een vergelijking met het getal 42 klopt daardoor niet. Zet er WAARDE omheen als je met getallen wilt vergelijken of rekenen.

Het aantal tekens vergeten

Zonder tweede argument geeft RECHTS alleen het laatste teken. Geef altijd op hoeveel tekens je wilt, zoals =RECHTS(A2;4).

Vragen over RECHTS

Wat is RIGHT in het Nederlands?

In Nederlandse Excel heet RIGHT RECHTS. LEFT heet LINKS en MID heet DEEL.

Hoe haal ik de laatste tekens weg?

Pak de rest met LINKS: =LINKS(A2;LENGTE(A2)-5) laat de laatste vijf tekens weg.

Hoe krijg ik de extensie van een bestandsnaam?

Bij extensies van drie letters werkt =RECHTS(A2;3). Zijn ze verschillend van lengte, gebruik dan in Microsoft 365 =TEKST.NA(A2;".";-1): alles na de laatste punt.

Hoe pak ik het laatste woord uit een tekst?

In Microsoft 365 met =TEKST.NA(A2;" ";-1): alles na de laatste spatie. In oudere versies kan het met een combinatie van RECHTS, SUBSTITUEREN en LENGTE, maar die formule is een stuk langer.